Lesson 11 of 12

A band

In VS Code, in an empty .lys file: type lesson, press Ctrl+Space and pick lesson-11-band.

More parts, same section. tab prints a part as tablature, clef percussion makes a drum part, and each score is one printout of the same music. The drums are lesson 10's patterns. pitch concert: write what sounds. pitch transposed on a score prints it for the player.

The lesson as it opens: the red rings mark where a step happens.

The score bassist.

The score trumpet.

Try

Pick trumpet or bassist at the top of the preview · in a part, Ctrl+Space after midiInstrument " lists the 128 sounds · hover hats to see its beat.

The whole lesson

// Lesson 11 of 12 — A band
// Preview: Ctrl+K V
//
// More parts, same section. `tab` prints a part as tablature, `clef percussion`
// makes a drum part, and each `score` is one printout of the same music.
// The drums are lesson 10's patterns.
// `pitch concert`: write what sounds. `pitch transposed` on a score prints it for the player.

title "Saturday"
composer "Lily# lessons"

tempo 112
pitch concert

part lead { instrument trumpet }
part bass { clef bass  tuning bass  octave 3 }
part kit { clef percussion }

phrase hats   { hh8 8 8 8 8 8 8 8 | }
phrase back   { r4 sn r sn | }
phrase kick   { bd4 r bd r | }
phrase groove { drums { hats back kick } }
phrase fill   { drums { { hh4 hh r2 | } { r2 tuplet 3/2 { sn8 sn sn tomh tomml tomfh } | } kick } }

section A {
  lead { e4 g a g | c2 a | g4 e d c | d1 | }
  bass { c4 c g c | a a e a | f f a f | g g b g | }
  kit { groove groove groove fill }
}

chords prog {
  section A { C | Am | F | G | }
}

form { |: ~A :| }

score {                          // the full band, as it sounds
  chords prog
  staff lead
  staff bass
  tab bass
  staff kit
}

score trumpet pitch transposed { // the trumpeter's part, a step up
  staff lead
}

score bassist {                  // just the bass part
  staff bass
  tab bass
}

// TRY: pick `trumpet` or `bassist` at the top of the preview · in a part,
// Ctrl+Space after `midiInstrument "` lists the 128 sounds · hover `hats` to see its beat.
//
// NEXT — type `lesson` on a new line and pick `lesson-12-chart`.

In the manual

• Transposing instruments
• Tablature
• Scores